-
Notifications
You must be signed in to change notification settings - Fork 0
/
step.ino
380 lines (310 loc) · 9.31 KB
/
step.ino
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
// © Kay Sievers <kay@versioduo.com>, 2020-2024
// SPDX-License-Identifier: Apache-2.0
#include <V2Base.h>
#include <V2Buttons.h>
#include <V2Color.h>
#include <V2Device.h>
#include <V2LED.h>
#include <V2Link.h>
#include <V2MIDI.h>
#include <V2Music.h>
#include <V2PowerSupply.h>
#include <V2Stepper.h>
V2DEVICE_METADATA("com.versioduo.step", 19, "versioduo:samd:step");
namespace {
constexpr uint8_t nSteppers{4};
V2LED::WS2812 LED(nSteppers + 2, PIN_LED_WS2812, &sercom2, SPI_PAD_0_SCK_1, PIO_SERCOM);
V2Link::Port Plug(&SerialPlug, PIN_SERIAL_PLUG_TX_ENABLE);
V2Link::Port Socket(&SerialSocket, PIN_SERIAL_SOCKET_TX_ENABLE);
V2Base::Timer::Periodic Timer(2, 200000);
V2Base::Analog::ADC ADC(V2Base::Analog::ADC::getID(PIN_VOLTAGE_SENSE));
class Stepper : public V2Stepper::Motor {
public:
Stepper(const Motor::Config conf, uint8_t index) :
Motor(conf, &Timer, &SPI, PIN_DRIVER_SELECT + index, PIN_DRIVER_STEP + index),
_index(index) {}
private:
const uint8_t _index;
void handleMovement(Move move) override {
switch (move) {
case Move::Forward:
LED.setHSV(_index, V2Color::Cyan, 1, 0.4);
break;
case Move::Reverse:
LED.setHSV(_index, V2Color::Orange, 1, 0.4);
break;
case Move::Stop:
LED.setHSV(_index, V2Color::Green, 1, 0.2);
break;
}
}
} Steppers[nSteppers]{
Stepper(
{
.ampere{0.5},
.microstepsShift{3},
.home{.speed{500}, .stall{0.045}},
.speed{.min{200}, .max{2000}, .accel{8000}},
},
0),
Stepper(
{
.ampere{0.5},
.microstepsShift{3},
.home{.speed{500}, .stall{0.045}},
.speed{.min{200}, .max{2000}, .accel{8000}},
},
1),
Stepper(
{
.ampere{0.5},
.microstepsShift{3},
.home{.speed{500}, .stall{0.045}},
.speed{.min{200}, .max{2000}, .accel{8000}},
},
2),
Stepper(
{
.ampere{0.5},
.microstepsShift{3},
.home{.speed{500}, .stall{0.045}},
.speed{.min{200}, .max{2000}, .accel{8000}},
},
3),
};
class Power : public V2PowerSupply {
public:
Power() : V2PowerSupply({.min{4.8}, .max{26}}) {}
void begin() {
pinMode(PIN_DRIVER_ENABLE, OUTPUT);
digitalWrite(PIN_DRIVER_ENABLE, HIGH);
}
private:
float handleMeasurement() override {
// A voltage 10/100k divider.
return 36.f * ADC.readChannel(V2Base::Analog::ADC::getChannel(PIN_VOLTAGE_SENSE));
}
void handleOn() override {
digitalWrite(PIN_DRIVER_ENABLE, LOW);
}
void handleOff() override {
digitalWrite(PIN_DRIVER_ENABLE, HIGH);
}
void handleNotify(float voltage) override {
// Power interruption, or commands without a power connection show yellow LEDs.
if (voltage < config.min) {
LED.splashHSV(0.5, V2Color::Yellow, 1, 0.5);
return;
}
// Over-voltage shows red LEDs.
if (voltage > config.max) {
LED.splashHSV(0.5, V2Color::Red, 1, 1);
return;
}
// The number of green LEDs shows the voltage.
const float fraction{voltage / (float)config.max};
const float n{ceil((float)nSteppers * fraction)};
LED.splashHSV(0.5, n, V2Color::Green, 1, 0.5);
}
} Power;
class Device : public V2Device {
public:
Device() : V2Device() {
metadata.vendor = "Versio Duo";
metadata.product = "V2 step";
metadata.description = "Stepper Motor Controller";
metadata.home = "https://versioduo.com/#step";
system.download = "https://versioduo.com/download";
system.configure = "https://versioduo.com/configure";
}
private:
struct {
int16_t pitchBend;
float rotate;
} _steppers[nSteppers]{};
void handleReset() override {
LED.reset();
for (uint8_t i = 0; i < nSteppers; i++) {
_steppers[i] = {};
Steppers[i].reset();
}
Power.off();
}
void allNotesOff() {
reset();
}
bool power() {
bool continuous;
if (!Power.on(continuous))
return false;
if (!continuous)
for (auto& s : Steppers)
s.reset();
return true;
}
void play(uint8_t channel, uint8_t note, uint8_t velocity) {
if (channel >= nSteppers)
return;
if (note < V2MIDI::C(3) || note > V2MIDI::B(4))
return;
if (velocity == 0) {
Steppers[channel].stop();
return;
}
if (!power())
return;
const float range{(float)(note - V2MIDI::C(3)) / 23.f};
const float speed{(float)velocity / 127.f};
Steppers[channel].position(range * 200.f * 3.f, powf(speed, 3));
}
void handleNote(uint8_t channel, uint8_t note, uint8_t velocity) override {
play(channel, note, velocity);
}
void handleNoteOff(uint8_t channel, uint8_t note, uint8_t velocity) override {
play(channel, note, 0);
}
void handleControlChange(uint8_t channel, uint8_t controller, uint8_t value) override {
if (channel != 0)
return;
switch (controller) {
case V2MIDI::CC::AllSoundOff:
case V2MIDI::CC::AllNotesOff:
allNotesOff();
break;
}
}
void handlePitchBend(uint8_t channel, int16_t value) override {
if (channel >= nSteppers)
return;
_steppers[channel].pitchBend = value;
// Negative range, the chosen exponent needs to preserve the sign.
const float fraction{(float)value / (value < 0 ? 8192.f : 8191.f)};
_steppers[channel].rotate = powf(fraction, 3);
if (!power())
return;
Steppers[channel].rotate(_steppers[channel].rotate);
}
void handleSystemReset() override {
reset();
}
void exportSystem(JsonObject json) override {
JsonObject jsonPower = json["power"].to<JsonObject>();
jsonPower["voltage"] = serialized(String(Power.getVoltage(), 1));
jsonPower["interruptions"] = Power.getInterruptions();
}
void exportInput(JsonObject json) override {
JsonArray jsonChannels = json["channels"].to<JsonArray>();
for (uint8_t ch = 0; ch < nSteppers; ch++) {
JsonObject jsonChannel = jsonChannels.add<JsonObject>();
jsonChannel["number"] = ch;
{
JsonObject jsonPitchbend = jsonChannel["pitchbend"].to<JsonObject>();
jsonPitchbend["value"] = _steppers[ch].pitchBend;
}
{
JsonObject jsonChromatic = jsonChannel["chromatic"].to<JsonObject>();
jsonChromatic["start"] = V2MIDI::C(3);
jsonChromatic["count"] = 24;
}
}
}
} Device;
// Dispatch MIDI packets.
class MIDI {
public:
void loop() {
if (!Device.usb.midi.receive(&_midi))
return;
if (_midi.getPort() == 0) {
Device.dispatch(&Device.usb.midi, &_midi);
} else {
_midi.setPort(_midi.getPort() - 1);
Socket.send(&_midi);
}
}
private:
V2MIDI::Packet _midi{};
} MIDI;
// Dispatch Link packets.
class Link : public V2Link {
public:
Link() : V2Link(&Plug, &Socket) {
Device.link = this;
}
private:
V2MIDI::Packet _midi{};
// Receive a host event from our parent device.
void receivePlug(V2Link::Packet* packet) override {
if (packet->getType() == V2Link::Packet::Type::MIDI) {
packet->receive(&_midi);
Device.dispatch(&Plug, &_midi);
}
}
// Forward children device events to the host.
void receiveSocket(V2Link::Packet* packet) override {
if (packet->getType() == V2Link::Packet::Type::MIDI) {
uint8_t address = packet->getAddress();
if (address == 0x0f)
return;
if (Device.usb.midi.connected()) {
packet->receive(&_midi);
_midi.setPort(address + 1);
Device.usb.midi.send(&_midi);
}
}
}
} Link;
class Button : public V2Buttons::Button {
public:
Button() : V2Buttons::Button(&_config, PIN_BUTTON) {}
private:
const V2Buttons::Config _config{.clickUsec{200 * 1000}, .holdUsec{500 * 1000}};
void handleClick(uint8_t count) override {
Device.reset();
}
void handleHold(uint8_t count) override {
LED.setHSV(nSteppers + 0, V2Color::Cyan, 1, 0.25);
LED.setHSV(nSteppers + 1, V2Color::Cyan, 1, 0.25);
}
void handleRelease() override {}
} Button;
}
void setup() {
Serial.begin(9600);
SPI.begin();
LED.begin();
LED.setMaxBrightness(0.5);
Plug.begin();
Socket.begin();
Device.link = &Link;
// Set the SERCOM interrupt priority, it requires a stable ~300 kHz interrupt
// frequency. This needs to be after begin().
setSerialPriority(&SerialPlug, 2);
setSerialPriority(&SerialSocket, 2);
Power.begin();
for (auto& s : Steppers)
s.begin();
// The priority needs to be lower than the SERCOM priorities.
Timer.begin([]() {
for (auto& s : Steppers)
s.tick();
});
Timer.setPriority(3);
ADC.begin();
ADC.addChannel(V2Base::Analog::ADC::getChannel(PIN_VOLTAGE_SENSE));
Device.begin();
Button.begin();
Device.reset();
}
void loop() {
for (auto& s : Steppers)
s.loop();
LED.loop();
MIDI.loop();
Link.loop();
V2Buttons::loop();
Power.loop();
Device.loop();
if (Link.idle() && Device.idle())
Device.sleep();
}