-
Notifications
You must be signed in to change notification settings - Fork 0
/
Medical.txt
157 lines (140 loc) · 3.48 KB
/
Medical.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
#pragma mode( separator(,;;) integer(h32) )
// (C) Copyright 2020 Manolis Christodoulou
// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU General Public License as published by
// the Free Software Foundation, either version 3 of the License, or
// (at your option) any later version.
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
// You should have received a copy of the GNU General Public License
// along with this program. If not, see <https://www.gnu.org/licenses/>.
EXPORT MELD(Bil;INR;Cr)
BEGIN
ROUND(3,78*LN(IFTE(Bil<1;1;Bil))
+11,2*LN(IFTE(INR<1;1;INR))
+9,57*LN(IFTE(Cr<1;1;Cr))+6,43;0);
END;
EXPORT MELD_Na(Bil;INR;Cr;Na)
BEGIN
ROUND(3,78*LN(IFTE(Bil<1;1;Bil))
+11,2*LN(IFTE(INR<1;1;INR))
+9,57*LN(IFTE(Cr<1;1;Cr))+6,43
+1,59*(135-Na);1);
END;
EXPORT MELDPLUS(Bil;INR;Cr;Na;Alb;WBC;Chol;Age)
BEGIN
LOCAL D;
INPUT(D;"Days in hospital";"";"";0;0);
LOCAL L1:={
11,79438;
2,076192*LOG(1+Bil);
2,525904*LOG(1+INR);
2,494291*LOG(1+Cr);
−6,62527*LOG(1+Na);
−6,04954*LOG(1+Alb);
1,911856*LOG(1+WBC);
−1,44567*LOG(1+Chol);
0,041047*Age;
0,015411*D
};
LOCAL L2:={
8,534995;
2,065032*LOG(1+Bil);
2,997248*LOG(1+INR);
2,596797*LOG(1+Cr);
−6,47834*LOG(1+Na);
−6,3499*LOG(1+Alb);
1,928117*LOG(1+WBC);
0,040704*Age
};
{e^ΣLIST(L1);e^ΣLIST(L2)};
END;
// Nasal masc FIO2
// LMin: L/min
EXPORT NASALFIO2(LMin)
BEGIN
20,9+4*LMin;
END;
// Total blood oxygen
// Hgb: %
// SO2: %
// PO2: mmHg
EXPORT TOTALO2(Hgb;SO2;PO2)
BEGIN
Hgb*1,34*SO2/100+PO2*0,0031;
END;
// Proton consentration based on Ph
EXPORT PH2H(Ph)
BEGIN
ALOG(9-Ph);
END;
// Body Surface area
// Weight: Kg
// Height: m
EXPORT BSA(Weight;Height)
BEGIN
0,007184*Weight^0,425*(Height*100)^0,725;
END;
// Henderson Hasellbaclch formula
EXPORT HENDHAS(HCO3;pCO2)
BEGIN
6,1+LOG(HCO3/0,03/pCO2);
END;
// Mean arterial pressure
EXPORT MAP(Systolic;Diastolic)
BEGIN
(Systolic+2*Diastolic)/3;
END;
// Water Defficit
// Na: Sodium (mEq/L)
// Weight: Kg
EXPORT WDEFF(Na;Weight)
BEGIN
0,6*((Na/140)-1)*Weight;
END;
// Corrected Sodium
// Na: Sodium mEq/L
// Glu: Glucose mg/dL
EXPORT CORRNA(Na;Glu)
BEGIN
Na+(Glu-100)*0,016;
END;
// Corrected Calcium
// Ca: Calcium mg/dL
// Alb: Serum Albumine g/dL
// NAlb: Normal value of serum albumine g/dL
EXPORT CORRCA(Ca;Alb;NAlb)
BEGIN
Ca+0,8*(NAlb-Alb);
END;
// Creatine Clearance Cockroft-Gault
// Weight: Kg
// Cr: Creatinine mg/dL
EXPORT CRCL(Age;Weight;Sex;Cr)
BEGIN
IF Sex≠1 AND Sex≠2 THEN RETURN 0; END;
ROUND((140-Age)*Weight*PIECEWISE(Sex=1;1;Sex=2;0,85)/(72*Cr);1);
END;
// eGFR CKD-EPI
// Cr: Creatinine mg/dL
// Sex: 1=male, 2=female
// Race: 1=non African American, 2=African American
EXPORT CKD_EPI(Age; Cr; Sex; Race)
BEGIN
IF Sex≠1 AND Sex≠2 THEN RETURN 0; END;
IF Race≠1 AND Race≠2 THEN RETURN 0; END;
LOCAL K:=PIECEWISE(Sex=1;0,9;Sex=2;0,7);
ROUND(0,993^Age*141*MIN(Cr/K;1)^PIECEWISE(Sex=1;−0,411;Sex=2;−0,329)*MAX(Cr/K;1)^−1,209*PIECEWISE(Race=1;1;Race=2;1,159)*PIECEWISE(Sex=1;1;Sex=2;1,018);1)
END;
// eGFR MDRD
// Cr: Creatinine mg/dL
// Sex: 1=male, 2=female
// Race: 1=non African American, 2=African American
EXPORT MDRD(Age; Cr; Sex; Race)
BEGIN
IF Sex≠1 AND Sex≠2 THEN RETURN 0; END;
IF Race≠1 AND Race≠2 THEN RETURN 0; END;
ROUND(186*Age^−0,203*Cr^−1,154*PIECEWISE(Sex=1;1;Sex=2;0,742)*PIECEWISE(Race=1;1;Race=2;1,212);1);
END;