Atlas in docker + terraform

[bodinsamuel]

Hey,

Started using atlas in a new project this week.
I wanted to integrate it into our terraform setup, here is what I did:

Provided a dead-simple dockerfile: https://hub.docker.com/repository/docker/algolia/atlasgo
(Could be cool to provide one by default)

# docker build --platform linux/x86_64 -f Dockerfile -t algolia/atlasgo:0.0.1 .
# docker push algolia/atlasgo:0.0.1

FROM golang:1.17-buster

RUN curl -LO https://release.ariga.io/atlas/atlas-linux-amd64-latest
RUN install -o root -g root -m 0755 ./atlas-linux-amd64-latest /usr/local/bin/atlas

RUN atlas version

Then terraform job to run migration

// Put the Atlas definition into a configmap so we don't need to build a specific image
resource "kubernetes_config_map" "db_state" {
  metadata {
    name = "db-state"
  }

  data = {
    "main.hcl" = "${file("${path.module}/../main.hcl")}"
  }
}

// This job is executed only if config_map changes
// So if the config_map does not change the migration is not executed again.
// NB: Job will be executed again if the image/settings changes but without side-effects so no worries
// You just need to add `depends_on = [ kubernetes_job.db_migrate ]` on the deployments that needs to wait for migration.
resource "kubernetes_job" "db_migrate" {
  metadata {
    name = "db-migrate"
  }

  wait_for_completion = true

  spec {
    backoff_limit           = 0 // never retry
    active_deadline_seconds = 90

    template {
      metadata {
        labels = {
          app = "db-migrate"
        }
      }

      spec {
        restart_policy = "Never"

        container {
          name              = "db-migrate"
          image             = "algolia/atlasgo:0.0.1"
          image_pull_policy = "Always"
          command = [
            "atlas",
            "schema",
            "apply",
            "-d",
            "postgres://migrator:$(PWD)@$(IP)/postgres", # PWD comes from the secret_ref, IP is up to your implem
            "-f",
            "/db_state/main.hcl",
            "--auto-approve"
          ]

          resources {
            requests = {
              cpu    = "200m"
              memory = "200Mi"
            }
            limits = {
              cpu    = "200m"
              memory = "200Mi"
            }
          }

          volume_mount {
            name       = "db-state"
            mount_path = "/db_state/"
          }

          env_from {
            secret_ref {
              name = kubernetes_secret.sql_user_migrator_pwd.metadata[0].name
            }
          }
        }

        volume {
          name = "db-state"
          config_map {
            name     = kubernetes_config_map.db_state.metadata.0.name
            optional = false
          }
        }
      }
    }
  }
}

[rotemtam]

Amazing work @bodinsamuel !

Thanks for sharing this. I want to share two things that we are working on that are completely in line with this direction:

1. A terraform provider - we want to make it easy for you to integrate atlas migrations into your normal TF workflows. The best way we can think of to do this is to supply a TF provider that you can use by providing an HCL as input to it.
2. An official atlas docker image (this should be out with the upcoming release).

I love this, thanks again for sharing!

[bodinsamuel]

amazing news ❤️

[rotemtam]

@bodinsamuel

Do you mind joining our Discord server?

I want to discuss this (and a few other issues you've opened in the past)

Thanks

[bodinsamuel]

Joined as h1fra feel free to DM or create a discussion ☺️